In this example, we will estimate a model for a four-stage evaporator to reduce the water content of a product, for example milk. The 3 inputs are feed flow, vapor flow to the first evaporator stage and cooling water flow. The three outputs are the dry matter content, the flow and the temperature of the outcoming product.

The example comes from STADIUS's Identification Database

Zhu Y., Van Overschee P., De Moor B., Ljung L., Comparison of three classes of identification methods. Proc. of SYSID '94,

using DelimitedFiles, Plots
using ControlSystemIdentification, ControlSystemsBase

url = "https://ftp.esat.kuleuven.be/pub/SISTA/data/process_industry/evaporator.dat.gz"
zipfilename = "/tmp/evaporator.dat.gz"
path = Base.download(url, zipfilename)
run(`gunzip -f $path`)
data = readdlm(path[1:end-3])
# Inputs:
# 	u1: feed flow to the first evaporator stage
# 	u2: vapor flow to the first evaporator stage
# 	u3: cooling water flow
# Outputs:
# 	y1: dry matter content
# 	y2: flow of the outcoming product
# 	y3: temperature of the outcoming product
u = data[:, 1:3]'
y = data[:, 4:6]'
d = iddata(y, u, 1)

InputOutput data of length 6305, 3 outputs, 3 inputs, Ts = 1

The input consists of two heating inputs and one cooling input, while there are 6 outputs from temperature sensors in a cross section of the furnace.

Before we estimate any model, we inspect the data

plot(d, layout=6)

We split the data in two, and use the first part for estimation and the second for validation. A model of order around 8 is reasonable (the paper uses 6-13). This system requires the option zeroD=false to be able to capture a direct feedthrough, otherwise the fit will always be rather poor.

dtrain = d[1:3300] # first experiment ends after 3300 seconds
dval = d[3301:end]

model,_ = newpem(dtrain, 8, zeroD=false)

Iter     Function value   Gradient norm
     0     7.796309e+02     2.166337e+02
 * time: 6.794929504394531e-5
    50     7.515894e+02     7.099459e+02
 * time: 4.396945953369141
   100     7.370387e+02     9.003382e+01
 * time: 7.9182960987091064
   150     7.319665e+02     6.576512e+01
 * time: 11.373755931854248
   200     7.300869e+02     1.292899e+01
 * time: 14.820507049560547
   250     7.297391e+02     1.721697e+01
 * time: 18.257965087890625
   300     7.296108e+02     6.794073e+00
 * time: 21.695936918258667
   350     7.295775e+02     1.496697e+01
 * time: 25.130647897720337
   400     7.295727e+02     2.003661e+00
 * time: 28.570642948150635
   450     7.295717e+02     2.628680e-01
 * time: 32.01832389831543

predplot(model, dval, h=1, layout=d.ny)
predplot!(model, dval, h=5, ploty=false)

The figures above show the result of predicting $h={1, 5}$ steps into the future.

We can visualize the estimated model in the frequency domain as well.

w = exp10.(LinRange(-2, log10(pi/d.Ts), 200))
sigmaplot(model.sys, w, lab="PEM", plotphase=false)

Let's compare prediction performance to the paper

ys = predict(model, dval, h=5)
ControlSystemIdentification.mse(dval.y-ys)

3×1 Matrix{Float64}:
 0.05761868868454413
 0.15635501751955702
 0.01926955681560514

The authors got the following errors: [0.24, 0.39, 0.14]