In this example, we will estimate a model for a four-stage evaporator to reduce the water content of a product, for example milk. The 3 inputs are feed flow, vapor flow to the first evaporator stage and cooling water flow. The three outputs are the dry matter content, the flow and the temperature of the outcoming product.

The example comes from STADIUS's Identification Database

Zhu Y., Van Overschee P., De Moor B., Ljung L., Comparison of three classes of identification methods. Proc. of SYSID '94,

using DelimitedFiles, Plots
using ControlSystemIdentification, ControlSystemsBase

url = "https://ftp.esat.kuleuven.be/pub/SISTA/data/process_industry/evaporator.dat.gz"
zipfilename = "/tmp/evaporator.dat.gz"
path = Base.download(url, zipfilename)
run(`gunzip -f $path`)
data = readdlm(path[1:end-3])
# Inputs:
# 	u1: feed flow to the first evaporator stage
# 	u2: vapor flow to the first evaporator stage
# 	u3: cooling water flow
# Outputs:
# 	y1: dry matter content
# 	y2: flow of the outcoming product
# 	y3: temperature of the outcoming product
u = data[:, 1:3]'
y = data[:, 4:6]'
d = iddata(y, u, 1)
InputOutput data of length 6305, 3 outputs, 3 inputs, Ts = 1

The input consists of two heating inputs and one cooling input, while there are 6 outputs from temperature sensors in a cross section of the furnace.

Before we estimate any model, we inspect the data

plot(d, layout=6)
Example block output

We split the data in two, and use the first part for estimation and the second for validation. A model of order around 8 is reasonable (the paper uses 6-13). This system requires the option zeroD=false to be able to capture a direct feedthrough, otherwise the fit will always be rather poor.

dtrain = d[1:3300] # first experiment ends after 3300 seconds
dval = d[3301:end]

model,_ = newpem(dtrain, 8, zeroD=false)
Iter     Function value   Gradient norm
     0     7.896730e+02     2.039439e+02
 * time: 4.9114227294921875e-5
    50     7.576979e+02     4.949210e+02
 * time: 4.411724090576172
   100     7.371685e+02     7.425400e+01
 * time: 8.539170026779175
   150     7.314175e+02     9.057465e+01
 * time: 12.510939121246338
   200     7.298207e+02     2.411944e+01
 * time: 16.480293035507202
   250     7.295993e+02     4.626991e+00
 * time: 20.446503162384033
   300     7.295811e+02     1.128630e+01
 * time: 24.405546188354492
   350     7.295731e+02     4.049161e+00
 * time: 28.371665000915527
   400     7.295718e+02     1.825033e-01
 * time: 32.34131217002869
   450     7.295717e+02     2.376313e-05
 * time: 36.302191972732544
predplot(model, dval, h=1, layout=d.ny)
predplot!(model, dval, h=5, ploty=false)
Example block output

The figures above show the result of predicting $h={1, 5}$ steps into the future.

We can visualize the estimated model in the frequency domain as well.

w = exp10.(LinRange(-2, log10(pi/d.Ts), 200))
sigmaplot(model.sys, w, lab="PEM", plotphase=false)
Example block output

Let's compare prediction performance to the paper

ys = predict(model, dval, h=5)
ControlSystemIdentification.mse(dval.y-ys)
3×1 Matrix{Float64}:
 0.05761868865692208
 0.15635501747372724
 0.01926955672029773

The authors got the following errors: [0.24, 0.39, 0.14]